Motion/Lightning Detect Take pictures when motion is detected.

• Number Of Columns (Default=6)
• Number Of Rows (Default=4)
• Treshold (0-255) (Default=24) recommended values: 10=Lightning, 12=Sunshine, 24=Cloudy, 36=Dawn/Dusk
• Comparison Interval (mSec) (Default=1)
• Triggering Delay (.1 Sec) (Default=0) recommended values: 0=Ultrafast(Lightning), 16=Normal, 32=Slow
• Pixel BlockSize (Default=8) number of pixels as one block (smaller size is more accurate but slower)
• Detection Mode (Default=1) values: 0=U, 1=Y, 2=V, 3=R, 4=G, 5=B
• Initial Delay (Sec) (Default=1)

rem Johan Van Barel 05-04-2008
rem Motion/Lightning-Detect for Canon A640

@title Motion Detect
@param a Cols
@default a 6
@param b Rows
@default b 4
rem Treshold: 10=Lightning, 12=Sunshine, 
rem Treshold: 24=Cloudy, 36=Dawn/Dusk
@param c Threshold (0-255)
@default c 24
@param d Interval (mSec)
@default d 1
rem Delay: 0=Ultrafast(Lightning), 16=Normal, 32=Slow
@param e Delay (.1 Sec)(0=UltraFast)
@default e 0
@param f BlockSize
@default f 8
@param g Mode(U=0,Y=1,V=2)
@default g 1
@param h Initial Delay (Sec)
@default h 1

if a<1 then a=1
if b<1 then b=1
if c<0 then c=0
if e<0 then e=0
if f<1 then f=1
if g<0 then g=0
if g>5 then g=5
if r<0 then r=0
if h<0 then h=0

e=e*100

rem time in msecs md will detect
x=5000

sleep h*1000

i=0
while 1
    if e=0 then
        press "shoot_half"
        do
            get_prop 205 p
        until p=1
    endif
    t=0
    md_detect_motion a,b,g,x,d,c,1,t,0,1,1,a,b,0,f,e
    if t>0 then
        click "shoot_full"
        do
            get_prop 205 p
        until p<>1
        i=i+1 
        print "Pic", i, "(blocks="; t; ")"
    endif
wend